Frage: Wie konvertiere ich eine CSV-Datei (Textdatenbank) in ein Excelsheet (ohne Excel)? |
Nachfolgend sehen Sie ein Beispielskript, mit dem Sie Daten aus einer CSV-Datei in ein
Excelsheet exportieren können. Sollte das Excelsheet noch nicht existieren, wird automatisch
eine neue Datei angelegt.
Anmerkung: Der IUSR_Rechnername benötigt das Recht "Ändern" um die Datei erstellen
oder ändern zu können.
[csvtoexcel.asp]
<%
' --- Zusammenstellen der Datenbankverbindungsinformationen
Dim strProvider
strProvider = "PROVIDER=Microsoft.Jet.OLEDB.4.0;"
' --- Bei Text- und CSV-Dateien (und bei einigen anderen Datenbankformaten
' --- auch) wird das Verzeichnis als Datenbank und die Dateien als Tabellen
' --- angesehen. Daher muss hier die Angabe des Verzeichnisses erfolgen
Dim strDirectory
strDirectory = "DATA SOURCE=" & Server.MapPath ("./") & "\;"
' --- Damit der
Dim strProperties
strProperties = "Extended Properties=Text;"
Dim strComplete
strComplete = strProvider & strDirectory & strProperties
' --- Öffnen der Verbindung
Set objConn = Server.CreateObject("ADODB.Connection")
objConn.open strComplete
' --- Angeben des Dateinamens des Excelsheets inkl. Pfadangabe.
Dim xls_path
xls_path = Server.MapPath("./") & "\xls_test.xls"
' --- Es wird ein Export aller Daten aus der CSV-Datei "test_csv.csv"
' --- in das Datenblatt "tabImport" der Exceldatei durchgeführt.
SQL = "SELECT * INTO [tabImport] IN """ & xls_path & """ ""EXCEL 5.0;"" FROM test_csv.csv"
' --- Ausführen des SQL-Statements
objConn.Execute SQL
' --- Schliessen und terminieren der Datenbankverbindung.
objConn.Close
Set objConn = Nothing
%>
Damit die Spaltennamen korrekt zugeordnet werden (für dieses Beispiel stehen diese NICHT in der
CSV-Datei) sollte man noch eine Datei namens schema.ini in das Verzeichnis der CSV-Datei stellen.
Diese beinhaltet verschiedene Informationen zur Textdatenbank (Spalten, Datentypen, ...)
Um Ihnen die Möglichkeit zu geben, dieses Beispiel auf Ihrem lokalen Webserver direkt auszuprobieren,
haben wir alle Dateien dieses Beispiels zum Download zur Verfügung gestellt.
artikel_99.zip [2 KB]
|
![Copyright 2000 - 2024 by Stefan Falz Webconsulting](images/sfw_copyright.gif) |
|